cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
project(rrea_feedback_threshold LANGUAGES C CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
endif()

option(WITH_GEANT4_UIVIS "Build with Geant4 UI and visualization drivers" OFF)
if(WITH_GEANT4_UIVIS)
  find_package(Geant4 REQUIRED ui_all vis_all)
else()
  find_package(Geant4 REQUIRED)
endif()

find_package(Threads REQUIRED)
include(${Geant4_USE_FILE})

include_directories(
  ${PROJECT_SOURCE_DIR}/src/include
  ${PROJECT_SOURCE_DIR}/src/src/msis/C
  ${Geant4_INCLUDE_DIRS}
)

file(GLOB SOURCES CONFIGURE_DEPENDS ${PROJECT_SOURCE_DIR}/src/src/*.cc)
file(GLOB HEADERS CONFIGURE_DEPENDS ${PROJECT_SOURCE_DIR}/src/include/*.hh)

set(MSIS_SOURCES
  ${PROJECT_SOURCE_DIR}/src/src/msis/C/nrlmsise-00.c
  ${PROJECT_SOURCE_DIR}/src/src/msis/C/nrlmsise-00_data.c
)

add_executable(rrea_feedback
  ${PROJECT_SOURCE_DIR}/src/rrea_feedback.cc
  ${SOURCES}
  ${HEADERS}
  ${MSIS_SOURCES}
)

target_link_libraries(rrea_feedback PRIVATE ${Geant4_LIBRARIES} Threads::Threads)

# Always compile the transport-heavy executable at -O3 (independent of build type;
# Release already implies it for GCC/Clang, this pins it for all configs).
if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  target_compile_options(rrea_feedback PRIVATE -Wall -Wextra -O3)
endif()

install(TARGETS rrea_feedback DESTINATION bin)
